Accurate Map Descriptions

If you have problems capturing room descriptions, titles and exits accurately in 3k, open up your map properties and drop one of these pieces of code into Map Script -> Active in Explore mode only:

Both versions rely on you exploring in verbose mode.

This version is designed to use the new cartography skill minimap.

zMud

#REGEX "mtDescCapture" {^(.*)} {#IF {%len( %trim( %left( "%1", 64))) > 0} {#VAR mtRoomDesc %concat( @mtRoomDesc, %crlf, "%1")}} "" {disable}
#REGEX {^(\S.{68})[\@\^\v\+\E].*} {
  #VAR mtRoomDesc %null
  #VAR mtRoomName %null
  #VAR mtRoomExit %null
  }
#COND {^(?mtRoomName:.+?)(?:\([a-zA-Z,]+\)|)\s{2}.*[@^V+E]+.*} {
  #TAG Name @mtRoomName
  } {reparse|regex}
#COND {^$} {#T+ mtDescCapture} {regex}
#COND {(* obvious exit??(*)?)} {
  #T- mtDescCapture
  #VAR mtRoomExit "%2"
  #VAR mtRoomDesc %concat( @mtRoomDesc, %crlf, "%1")
  #TAG Exit @mtRoomExit
  #TAG Desc @mtRoomDesc
  }
#COND {^ +(.*)$$} {
  #VAR mtRoomExit %concat( @mtRoomExit, " ", "%1")
  #VAR mtRoomDesc %concat( @mtRoomDesc, %crlf, "%1")
  #TAG Exit @mtRoomExit
  #TAG Desc %1
  } {within|param=1|regex}

CMUD

#REGEX "mtDescCapture" {^(.*)} {#IF {%len( %trim( %left( %1, 64))) > 0} {#VAR mtRoomDesc %concat( @mtRoomDesc, %crlf, %1)}} "System|_MapperExplore" {disable}
#REGEX {^(\S.{68})[@^v+\E].*} {#VAR mtRoomDesc %null;#VAR mtRoomName %null;#VAR mtRoomExit %null} "System|_MapperExplore"
#COND {^(?:>\s|)(.*)\(([a-z,]*)\).*$}  {#TAG Name %quote( %trim( %stripq( "%1")));#VAR mtRoomName %quote( %trim( %stripq( "%1")))} {reparse|regex}
#COND {^$} {#T+ mtDescCapture} {regex}
#COND {(* obvious exit??(*)?)} {#T- mtDescCapture;#VAR mtRoomExit %2;#VAR mtRoomDesc %concat( @mtRoomDesc, %crlf, %1);#TAG Exit @mtRoomExit;#TAG Desc @mtRoomDesc}
#COND {^ +(.*)$} {#VAR mtRoomExit %concat( @mtRoomExit, " ", %trim(%1));#VAR mtRoomDesc %concat( @mtRoomDesc, %crlf, %1);#TAG Exit @mtRoomExit;#TAG Desc %1} {within|param=1|regex}

#NOMAP {This place appears to have never before been disturbed.}
#NOMAP {You have never been here before.}

And this version is for the old compass rose exit display.

zMud

#TRIGGER "tCaptureDesc" {^(*)} {#IF {%len( %trim( %left( "%1", 64))) > 0} {#VAR vRoomDesc %concat( @vRoomDesc, %crlf, "%1")}} "" {disable}
#TRIGGER {^(*)%s?%s-?-~*-} {#TAG Name %1} "" {skip|param=2}
#COND {*} {
  #VAR vRoomDesc ""
  #VAR vLastDescLine ""
  #T+ tCaptureDesc
  }
#COND {* obvious exit??(*)?} {
  #T- tCaptureDesc
  #VAR vExits "%1"
  #TAG Exit @vExits
  #TAG Desc @vRoomDesc
  }
#COND {^ +(.*)$$} {
  #VAR vExits %concat( @vExits, " ", "%1")
  #TAG Exit @vExits
  } {within|param=1|regex}
Unless otherwise stated, the content of this page is licensed under Creative Commons Attribution-ShareAlike 3.0 License